Quick basic

11) funciones matemáticas

• ABS:

Devuelve el valor absoluto de un numero.

Ejemplo:

CLS
COLOR 2: PRINT TAB(20); "VALOR ABSOLUTO" : COLOR 7
PRINT : INPUT "Introduce un número negativo (-a): ", a
PRINT : PRINT "El valor absoluto de "; a; "es"; : COLOR 2: PRINT ABS(a) : COLOR 7

Para mas información escribe ABS y luego presiona F1.

• SIN:

Devuelve el seno de x, donde x es un ángulo dado en radianes.

Ejemplo:

'Calcula la componente vertical de la velocidad de un misil
CONST pi = 3.1416

CLS
COLOR 2: PRINT TAB(20); "Componente Vertical" : COLOR 7
PRINT : INPUT "Introduzca la velocidad (m / s) del misil: ", v
PRINT : INPUT "Introduzca el ángulo (en grados) del lanzamiento: ", grados
radianes = grados * pi / 180
vy = v * SIN(radianes)
PRINT : PRINT "La velocidad vertical del misil es de"; vy; "m / s"

Como son muy comunes las conversiones de grados a radianes, para hacer esto se utiliza la fórmula:

radianes = (grados * 3.1416) / 180

Para mas información escribe SIN y luego presiona F1.

• COS:

Devuelve el coseno de x, donde x es un ángulo en radianes.

Ejemplo:

'Calcula la componente horizontal de la velocidad de un misil
CONST pi = 3.1416

CLS
COLOR 2: PRINT TAB(20); "Componente Horizontal" : COLOR 7
PRINT : INPUT "Introduzca la velocidad (m / s) del misil: ", v
PRINT : INPUT "Introduzca el ángulo (en grados) del lanzamiento: ", grados
vx = v * COS(grados * pi / 180)
PRINT : PRINT "La velocidad horizontal del misil es de"; vx; "m / s"

Para mas información escribe COS y luego presiona F1.

• TAN:

Devuelva la tangente de x, donde x es un ángulo en radianes.

Ejemplo:

CONST pi = 3.1416

CLS
INPUT "Introduce el ángulo de una recta: ", grados
PRINT "Tangente de la recta:"; : COLOR 15: PRINT TAN(grados * pi / 180)
PRINT : COLOR 7
INPUT "Presione <ENTER> para continuar", enter$

Para mas información escribe TAN y luego presiona F1.

• ATN:

Devuelve la arcotangente de una expresión numerica, osea, la inversa de la tangente.

'Calcula el ángulo del misil a partir de los componentes de la velocidad
CONST pi = 3.1416

CLS
INPUT "Introduzca la velocidad horizontal: ", vx
INPUT "Introduzca la velocidad vertical: ", vy

'Si la componente en x de la velocidad es 0 se producirá un error ya
'que estaremos dividiendo entre 0. Esto lo puedes arreglar con un IF

v = vy / vx
radianes = ATN(v) 'ATN devolverá un resultado en RADIANES
grados = (radianes * 180) / pi

PRINT "El ángulo (en grados) del lanzamiento es:"; : COLOR 15: PRINT grados
PRINT : COLOR 7
INPUT "Presione <ENTER> para continuar", enter$

Para mas información escribe ATN y luego presiona F1.

• LOG:

Devuelve el logaritmo natural (base e) de x, y donde x es un valor mayor que cero.

CLS
PRINT "El logaritmo natural de 9 es:"; LOG(9)

Para mas información escribe LOG y luego presiona F1.

• EXP:

Devuelve e elevado a una potencia especificada x, donde x es un valor menor o igual a 88.02969. A esta función se le llama antilogaritmo.

CLS
n = 9
PRINT "e elevado a la potencia:"; n; "da"; EXP(n)

Para mas información escribe EXP y luego presiona F1.

• SWAP:

Intercambia los valores de dos variables.

x = 5 : y = - 3

CLS
COLOR 15 : PRINT "Primero:"
COLOR 7: PRINT "x ="; x ; "y ="; y
SWAP x, y
COLOR 15 : PRINT "Luego:"
COLOR 7: PRINT "x ="; x ; "y ="; y

Para mas información escribe SWAP y luego presiona F1.

• FIX:

Le quita los decimales a x, siendo x un numero real.
La función FIX trunca un entero, no lo redondea.

CLS
n = 3.1416
PRINT "Si le quitamos los decimales a"; n; "el resultado es:"; FIX(n)

Para mas información escribe FIX y luego presiona F1.

• INT:

Redondea x al número menor inmediato que sea menor o igual a x.

n = 3.65
CLS
PRINT "Si redondeamos con INT a"; n; "el resultado es"; INT(n)

Para mas información escribe INT y luego presiona F1.

• SQR:

Calcula la raíz cuadrada de un número o expresión mayor o igual a cero.

CLS : COLOR 15
PRINT TAB(15); "CÁLCULO DE LA HIPOTENUSA A PARTIR DE LOS CATETOS"
PRINT : PRINT : COLOR 7
INPUT "Cateto opuesto: ", cop
INPUT "Cateto adyacente: ", cad
hip = SQR(cop * cop + cad * cad)
PRINT
PRINT "La hipotenusa vale"; : COLOR 15: PRINT hip

Para mas información escribe SQR y luego presiona F1.

• SGN:

Devuelve un valor indicando el signo de una expresión numerica.

La función SGN trabaja de la siguiente forma:

· Si x es negativo, SGN devuelve -1.
· Si x es cero, SGN devuelve 0.
· Si x es positivo, SGN devuelve 1.

Para mas información escribe SGN y luego presiona F1.

Descargar gratis los programas y compiladores necesarios para aprender a programar

  ¿Buscas algo?

Regresar al índice de quick basic

Regresar a la página principal